1つのMCPイメージをBedrock AgentCoreの2つのRuntimeで動かす — 他のAWSアカウントにはSigV4、ユーザーにはEntra ID
1つのMCPサーバーイメージを2つのBedrock AgentCore Runtimeとして動かす。クロスアカウントの呼び出し元にはリソースベースポリシー付きのIAM SigV4、ユーザーにはEntra IDのJWTで認証するRuntimeを用意した。

目次
はじめに
Amazon Bedrock AgentCore Runtime で MCP サーバーを運用しています。このサーバーを最初に使うエージェントは、別の AWS アカウントにありました。そのエージェントの ECS タスクから接続しようとすると、トークンを発行する Amazon Cognito のドメインにも、AgentCore のエンドポイントにも到達できませんでした。原因はおそらく、宛先単位で通信を遮断する送信フィルタでした。
送信フィルタに 2 つのホストを追加すれば、このエージェントは通るようになります。ただ、ほかの呼び出し元もすべて同じ問題にぶつかります。Cognito のトークンエンドポイントは PrivateLink のない公開 Web ドメインなので、トークンを取得するたびにリクエストが呼び出し元の VPC の外へ出ていきます。
Runtime を IAM SigV4 に切り替え、同じイメージでもう 1 つ Entra ID で認証する Runtime を動かしました。これで他の AWS アカウントは AWS のホスト名 1 つだけを呼び出せばよくなり、その通信は VPC エンドポイントでインターネットに出さずに済みます。呼び出しているのがどのユーザーかを知る必要があるツールは、Entra ID 版 Runtime にだけ置いています。
1 つのイメージ、2 つの Runtime
1 つのコンテナイメージが 2 つの AgentCore Runtime として動いており、それぞれの Runtime が受け付ける呼び出し元は 1 種類だけです。IAM 版 Runtime は、他の AWS アカウントのロールから AWS Signature Version 4(SigV4)で署名されたリクエストを受け付けます。Entra ID 版 Runtime は、ユーザーの MCP クライアントから Microsoft Entra ID のアクセストークンを受け付けます。
2 つの Runtime は、1 本の CI パイプライン、1 つのイメージタグ、1 つの Terraform モジュールから作られます。AUTH_MODE という環境変数が、コンテナ内での唯一の違いです。IAM 版 Runtime は iam を設定し、共通ツールを登録します。Entra ID 版 Runtime は entra を設定し、サインイン中のユーザーの代わりに動くツール(ユーザーのプロフィールの読み取りなど)も登録します。
Cognito のトークンエンドポイントはインターネット上に残る
AgentCore Runtime のインバウンド認証は 2 種類から選びます。カスタム JWT Authorizer が検証する JWT か、IAM SigV4 です。Runtime に authorizer_configuration を設定すると JWT になります。設定しなければ SigV4 になり、こちらがデフォルトです。
JWT と Cognito の組み合わせでは、呼び出し元は 2 か所と通信します。まず Cognito のホストドメイン <your-domain>.auth.<region>.amazoncognito.com から client_credentials グラントでトークンを取得し、次にそのトークンで AgentCore を呼び出します。
ホストドメインは AWS API のエンドポイントではなく Web サービスなので、対応する VPC エンドポイントがありません。Cognito にも VPC エンドポイントはありますが、トークンを発行するホストドメインは対象外です。Cognito の PrivateLink のページにも、client credentials グラントでのトークン取得は PrivateLink に対応しておらず、ユーザープールのドメインにはインターネット経由でしか到達できないと書かれています。そのため JWT を使う呼び出し元には、常にインターネットへの経路が必要です。
SigV4 ならトークンのリクエストが要りません。呼び出し元は自分の IAM 認証情報で各リクエストに署名するので、残る宛先は bedrock-agentcore.<region>.amazonaws.com だけです。AgentCore は bedrock-agentcore のホスト向けにインターフェース VPC エンドポイント com.amazonaws.<region>.bedrock-agentcore を提供しているので、呼び出し元のアカウントは通信を自分の VPC 内に留められます。
Runtime から authorizer_configuration を削除し、認証方式を JWT から SigV4 に切り替えました。
Runtime とそのエンドポイントの両方にリソースベースポリシーを付ける
別のアカウントのロールが Runtime を呼び出せるのは、Runtime のリソースベースポリシーにそのロールが載っているときだけです。アカウントをまたぐ場合、呼び出し元自身の IAM ポリシーだけでは足りません。
AgentCore は InvokeAgentRuntime を 2 つのリソースに対して評価します。Runtime 自体と、その DEFAULT エンドポイントです。それぞれに専用のポリシーが必要です。Runtime にだけポリシーを付けると、呼び出しは 403 で失敗します。この 403 からは、2 つのどちらが拒否したのかがわかりません。
DEFAULT エンドポイントは CreateAgentRuntime が自動で作るので、私の Terraform では宣言していません。その ARN は、Runtime の ARN の後ろに /runtime-endpoint/DEFAULT を付けたものです。両方の ARN を組み立て、それぞれにポリシーを 1 つずつ付けています。
locals { agentcore_policy_targets = ( var.exists_ecr_images && var.authorizer == null && length(var.invoker_principal_arns) > 0 ) ? { runtime = aws_bedrockagentcore_agent_runtime.this[0].agent_runtime_arn endpoint = "${aws_bedrockagentcore_agent_runtime.this[0].agent_runtime_arn}/runtime-endpoint/DEFAULT" } : {}}
data "aws_iam_policy_document" "agentcore_invoke" { for_each = local.agentcore_policy_targets statement { sid = "AllowCrossAccountInvoke" effect = "Allow" principals { type = "AWS" identifiers = var.invoker_principal_arns } actions = ["bedrock-agentcore:InvokeAgentRuntime"] resources = [each.value] }}
resource "aws_bedrockagentcore_resource_policy" "invoke" { for_each = local.agentcore_policy_targets resource_arn = each.value policy = data.aws_iam_policy_document.agentcore_invoke[each.key].json}for_each は map の項目ごとにブロックを 1 つずつ作ります。この map には runtime と endpoint の 2 項目があり、データソースもリソースと同じ for_each で回るので、Runtime に付くポリシーには Runtime の ARN が、DEFAULT エンドポイントに付くポリシーには DEFAULT エンドポイントの ARN が書かれます。
ロールに付けるポリシーでは、* はすべてのリソースを意味します。リソースベースポリシーはリソース自体に保存されます(S3 は PutBucketPolicy、AgentCore は PutResourcePolicy)。そのため S3 は * を、ポリシーを保存しているバケットと解釈します。AgentCore もポリシーをリソースに保存しますが、Resource にはポリシーを保存しているリソースの ARN を明記する必要があります。Terraform が DEFAULT エンドポイントに保存するポリシーは次のとおりです。
{ "Effect": "Allow", "Principal": { "AWS": "arn:aws:iam::444455556666:role/caller-agent" }, "Action": "bedrock-agentcore:InvokeAgentRuntime", "Resource": "arn:aws:bedrock-agentcore:us-east-1:111122223333:runtime/mcp_server-AbCdEf1234/runtime-endpoint/DEFAULT"}Runtime を呼び出せる呼び出し元は、モジュールの Terraform 変数 invoker_principal_arns に列挙し、ポリシーの Principal は invoker_principal_arns から生成されます。invoker_principal_arns に指定できるのは、ロールかユーザーの ARN だけです。arn:aws:iam::111122223333:root のようなアカウントのルートは、変数のバリデーションで拒否します。ルートを許可すると、ルートが属するアカウントのすべてのプリンシパルに Runtime が開放されてしまうからです。
クロスアカウントの呼び出しが通過しなければならない 3 つの場所
クロスアカウントの呼び出しが成功するのは、IAM ポリシーとリソースベースポリシーの両方が許可し、どの制限にも遮られなかったときだけです。3 つの場所のどれか 1 つで引っかかっても、返ってくるのは同じ 403 です。
- 呼び出し元の IAM ポリシーが、Runtime の ARN と
<runtime-arn>/runtime-endpoint/*に対してbedrock-agentcore:InvokeAgentRuntimeを許可していること。リソースベースポリシーと同じく、IAM ポリシーにも Runtime とエンドポイントの両方を書く必要があり、Runtime だけを指定したポリシーは拒否されます。 - 呼び出し元の Permissions Boundary と VPC エンドポイントポリシーが、呼び出しを遮らないこと。Permissions Boundary は権限の上限なので、Permissions Boundary に含まれないアクションは、ロール自身のポリシーが何を許可していても拒否されたままです。VPC エンドポイントポリシーはエンドポイントを通れるプリンシパルを制限できるので、呼び出し元のロールが含まれていなければ、呼び出しはエンドポイントで遮られます。
- サーバー側のリソースベースポリシーが、Runtime と
DEFAULTエンドポイントの両方で呼び出し元のロールを許可していること。
呼び出し元がロールに付ける IAM ポリシー(1 つ目の項目)は次のとおりです。
data "aws_iam_policy_document" "mcp_server_invoke" { statement { effect = "Allow" actions = ["bedrock-agentcore:InvokeAgentRuntime"] resources = [ var.mcp_server_runtime_arn, "${var.mcp_server_runtime_arn}/runtime-endpoint/*", ] }}3 つの場所のどれか 1 つで引っかかれば 403 になるので、2 つのアカウントの反映の順番も重要です。サーバー側のリソースベースポリシーを先に適用し、その後で呼び出し元を Runtime に向けます。順番が逆だと、サーバー側の変更が適用されるまで、呼び出し元からの呼び出しはすべて 403 を返します。
署名処理に Content-Type だけを渡す理由
呼び出し元はサービス名 bedrock-agentcore で署名し、botocore に渡すヘッダーは Content-Type だけにします。botocore は Content-Type と、botocore が追加する host や X-Amz-* ヘッダーをまとめて署名します。AgentCore の API は、用途によって 2 つのサービス名で署名します。
bedrock-agentcore-control:CreateAgentRuntimeなど、Runtime を作成・管理する API。bedrock-agentcore:Runtime を呼び出すInvokeAgentRuntime。本記事の呼び出し元が使うサービス名です。
Content-Type だけを渡すのは、署名後に httpx やプロキシがほかのヘッダーを書き換えることがあるからです。httpx のヘッダーをすべて botocore に渡すと、accept-encoding などのヘッダーまで署名に含まれます。書き換えが起きると署名が無効になり、その結果の 403 は権限不足とまったく見分けがつきません。
MCP の Python SDK は httpx(Python の HTTP クライアント)でリクエストを送るので、署名処理は httpx.Auth、つまり httpx が各リクエストの送信前に実行する認証処理として実装しています。署名処理はリクエストを botocore(AWS SDK for Python の土台になっているライブラリ)の AWSRequest にコピーして署名し、botocore が追加したヘッダーだけを httpx のリクエストに書き戻します。
class _SigV4Auth(httpx.Auth): # botocore がボディをハッシュするので、auth_flow の実行前に httpx がボディをバッファしておく必要がある。 requires_request_body = True
def auth_flow(self, request): aws_request = AWSRequest( method=request.method, url=str(request.url), data=request.content, headers={ "Content-Type": request.headers.get("content-type", "application/json"), }, ) frozen = credentials.get_frozen_credentials() SigV4Auth(frozen, "bedrock-agentcore", region).add_auth(aws_request) request.headers.update(signed_headers(dict(aws_request.headers))) yield request- 本文をバッファする:
requires_request_body = Trueにより、httpx はauth_flowの実行前に本文をメモリに読み込みます。botocore は本文をハッシュするので、先に本文全体が必要です。 Content-Typeだけをコピーする:AWSRequestにはContent-Typeと本文だけを入れるので、httpx のほかのヘッダーは署名に含まれません。- 一貫した認証情報を取る:ECS タスクロールの一時認証情報は定期的に更新されます。
get_frozen_credentials()はリクエストごとに一貫したスナップショットを 1 つ取るので、アクセスキーとセッショントークンが更新前と更新後から別々に取られることはなく、組み合わせの不一致で署名が失敗することもありません。 bedrock-agentcoreで署名する:SigV4Authはサービス名bedrock-agentcoreで署名し、AWSRequestにAuthorizationとX-Amz-*ヘッダーを追加します。- 署名用のヘッダーだけを書き戻す:
signed_headers()はAuthorizationとX-Amz-*のヘッダーだけを残してほかを捨て、httpx のリクエストに書き戻します。
Entra ID のユーザー向けに 2 つ目の Runtime を用意する
SigV4 で識別できるのは IAM ロールまでで、個人は識別できません。そのため IAM 版 Runtime へのリクエストは、すべて同じ呼び出し元から来たように見えます。特定のユーザーのために動くツールにはそのユーザーの ID が必要で、それを運ぶのが Entra ID のアクセストークンです。各 Runtime が受け付けるインバウンド認証は 1 種類だけなので、ユーザー固有ツールには 2 つ目の Runtime が必要でした。
2 つ目の Runtime にも同じイメージを使い、同じ Terraform モジュールの 2 回目の呼び出しとして追加しました。モジュールは省略可能な authorizer オブジェクトを受け取り、authorizer を渡すのは Entra ID 版の呼び出しだけです。
module "compute" { source = "../../modules/agentcore_runtime" runtime_name = local.runtime_name image_tag = var.image_tag invoker_principal_arns = local.invoker_principal_arns environment_variables = local.runtime_environment_variables # AUTH_MODE = "iam"}
module "compute_entra" { source = "../../modules/agentcore_runtime" runtime_name = local.entra_runtime_name image_tag = var.image_tag authorizer = { discovery_url = "https://login.microsoftonline.com/${local.entra_tenant_id}/v2.0/.well-known/openid-configuration" allowed_audience = local.entra_audience allowed_scopes = ["invoke"] } environment_variables = local.entra_environment_variables # AUTH_MODE = "entra"}モジュールに authorizer を渡すと、モジュールは次のように動きます。
authorizer_configurationを設定するrequest_header_allowlistでAuthorizationヘッダーをコンテナに転送し、コンテナがユーザーのクレームを読めるようにする- リソースベースポリシーをオフにする(JWT の Runtime はそもそも SigV4 で呼び出せないため)
既存の module "compute" のアドレス(Terraform が state でこのリソース群を追跡するときの名前)と runtime_name は変えていません。runtime_name を変えると Runtime が置き換えられ、新しい Runtime には新しい ARN が付きます。呼び出し元の IAM ポリシーもサーバー側のリソースベースポリシーも古い ARN を指しているので、両方を書き換えるまで呼び出しは拒否されます。
| 方法 | 具体的な形 | 重複するもの |
|---|---|---|
| 環境ディレクトリを分ける | environments/ の下に environments/dev-entra/ などのディレクトリを作り、Terraform の設定を別に持つ | シークレット、ECR の設定、CI のジョブ |
| アプリケーションのディレクトリを分ける | MCP サーバーのコードをもう 1 つコピーし、それぞれ別のイメージにビルドする | 共通ツールのコード(2 つのコピーは次第に食い違う) |
module ブロックを 2 つ書く(採用) | 同じ environments/dev/main.tf に module ブロックを 2 つ書き、どちらの source も同じモジュールを指す | なし |
最終的に、同じモジュールを参照する module ブロックを 2 つ書く方法を選びました。2 つの Runtime は同じ VPC にあり、必要な通信ルールも同じなので、セキュリティグループも 1 つを共有しています。
AUTH_MODE でユーザー固有ツールを Entra ID 版 Runtime にだけ登録する
サーバーが登録したツールはすべて tools/list(MCP クライアントがツール一覧を取得するリクエスト)のレスポンスに現れ、モデルは一覧のどのツールでも選べます。サーバーが登録していないツールは選ばれようがないので、IAM 版 Runtime ではユーザー固有ツールを一切登録しません。
# AUTH_MODE が未設定か想定外の値なら "iam" として扱う。値の欠落やタイプミスがあっても、# ユーザー固有ツールを持たない Runtime の側に倒れる(fail closed)ので、# ユーザー固有ツールを誤って公開することはない。AUTH_MODE = os.getenv("AUTH_MODE", "iam")
if AUTH_MODE == "entra": tools_user.register(mcp)AUTH_MODE が欠けていたり綴りを間違えていたりすると、コンテナは IAM 版 Runtime として動き、ユーザー固有ツールを登録しません。サーバーの状態を返す診断用のツールは auth_mode も返します。2 つの Runtime は同じイメージで動いているので、ユーザー固有ツールが見当たらないとき、呼び出す Runtime を間違えたのか AUTH_MODE の設定を間違えたのかは、auth_mode を見て初めて区別できます。
AgentCore の JWT Authorizer の後でコンテナが確認すること
AgentCore の Authorizer は、リクエストがコンテナに届く前に、トークンの署名、有効期限、オーディエンス、スコープを検証します。トークンの scp クレームには、invoke User.Read のように、トークンに与えられたスコープが並びます。scp に invoke がなければ、allowed_scopes = ["invoke"] によって Authorizer がリクエストを拒否します。
AgentCore は allowed_scopes を使って、次の 2 か所も埋めます。
- Runtime の OAuth Protected Resource Metadata(MCP クライアントがトークンの取得先を調べるドキュメント)にある
scopes_supported - 401 の
WWW-Authenticateヘッダーに入るスコープ
MCP クライアントは scopes_supported と WWW-Authenticate を見て、どのスコープを要求すればよいかを知ります。
Entra ID の v2 トークンは scp にスコープ名だけを入れるので、allowed_scopes の値は api://<client-id>/…/invoke ではなく invoke です。
Authorizer は tid と iss の値を照合せず、scp があるかどうかも確認しないので、コンテナがユーザー固有の呼び出しのたびに自分で確認します。トークンはすでに検証済みなので、コンテナはペイロードを base64url でデコードするだけです。
if not expected_tenant or str(tid).lower() != expected_tenant.lower(): raise AuthError("tenant mismatch")
expected_issuer = f"https://login.microsoftonline.com/{expected_tenant}/v2.0"if str(payload.get("iss", "")).lower() != expected_issuer.lower(): raise AuthError("issuer mismatch")
if not payload.get("scp"): raise AuthError("token has no scp claim: app-only (client_credentials) tokens cannot use user-specific tools")- テナント:
tidは想定するテナント ID と一致している必要があり、想定するテナントが設定されていなければすべて拒否します。エラーにはテナント ID を含めないので、メッセージがテナント ID を推測する手がかりになることはありません。 - 発行者:
issはhttps://login.microsoftonline.com/<テナント ID>/v2.0、つまり想定するテナントの v2 の発行者である必要があります。 scpの有無:client_credentialsグラントで取得したアプリ専用トークンにはscpがありません。このチェックがユーザーを経由しない抜け道を塞ぐので、CI の ID では個人のデータを読むツールを呼び出せません。
まとめ
別の AWS アカウントの呼び出し元が、AWS のホスト名 1 つだけを、自アカウントの VPC エンドポイント経由で呼び出せるように、MCP サーバーを Cognito の JWT から IAM SigV4 に移しました。そのうえで、同じイメージから Entra ID 版 Runtime を追加しました。SigV4 が識別するのはロールで、ユーザー固有ツールにはどのユーザーが呼び出しているかの識別が必要だからです。
- SigV4 を使うときは
authorizer_configurationを設定しません。AgentCore が受け付けるのは Runtime ごとに SigV4 か JWT のどちらか一方で、この設定の有無で決まるからです。 - リソースベースポリシーを Runtime と
<runtime-arn>/runtime-endpoint/DEFAULTの両方に付け、それぞれにポリシーが付くリソースの正確な ARN を書きます。 - 呼び出し元には Runtime と
/runtime-endpoint/*に対するInvokeAgentRuntimeを許可し、呼び出し元の Permissions Boundary と VPC エンドポイントポリシーも確認します。3 つの場所のどれか 1 つで引っかかれば 403 が返るからです。 - 署名には
bedrock-agentcoreを使い、botocore に渡すヘッダーはContent-Typeだけにします。 - ユーザー固有ツールは Entra ID 版 Runtime にだけ登録し、
AUTH_MODEのデフォルトはユーザー固有ツールを登録しないiamにします。 tidとissの値の照合とscpの有無の確認は、コンテナで行います。AgentCore の Authorizer が確認するのは、署名、有効期限、オーディエンス、スコープだけです。



